//
// Copyright(C) 2014-2015 Samuel Villarreal
//
// This program is free software; you can redistribute it and/or
// modify it under the terms of the GNU General Public License
// as published by the Free Software Foundation; either version 2
// of the License, or (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU General Public License for more details.
//
// DESCRIPTION:
//      Custom Object Class for Catacomb Puzzle
//

#include "scripts/common.txt"

/*
==============================================================
TurokCatacombWater
==============================================================
*/

class TurokCatacombWater : BPR::CL_BPR_WorldObject //[BP_Randomizer]
{
    kActor @self;
    bool bActivated;
    bool bDrained;
    
    TurokCatacombWater(kActor @actor)
    {
		super(actor); //[BP_Randomizer]
        @self = actor;
        bActivated = false;
        bDrained = false;
    }
    
    /*
    ==============================================================
    OnTick
    ==============================================================
    */
    
    void OnTick(void)
    {
        if(!bActivated || self.Type() != AT_DYNAMIC_WATER1)
        {
            return;
        }
        
        if(bDrained)
        {
            return;
        }
        
        if((self.GameTicks() & 95) == 0)
        {
            self.PlaySound("sounds/shaders/river_flow_heavy.ksnd");
        }
        
        self.Origin().z -= 1.0f;
        World.ChangeAreaWaterHeight(self.AreaID(), self.Origin().z);
        
        if(self.Origin().z < self.StepHeight())
        {
            bDrained = true;
            World.FloodFillAreaFlags(self.SectorIndex(), AAF_WATER, false);
        }
    }
    
    /*
    ==============================================================
    OnSpawn
    ==============================================================
    */
    
    void OnSpawn(void)
    {
    }
    
    /*
    ==============================================================
    OnActivate
    ==============================================================
    */
    
    void OnActivate(void)
    {
        int area;
        
        if(bActivated)
        {
            return;
        }
        
        bActivated = true;
        self.PlaySound("sounds/shaders/river_flow_heavy.ksnd");
        self.MarkPersistentBit(false);
        
        if(self.Type() == AT_DYNAMIC_WATER2)
        {
            self.Origin().z = self.StepHeight();
            
            area = self.AreaID();
            
            if(area <= -1)
            {
                return;
            }
            
            World.ChangeAreaFlag(area, AAF_DAMAGE, false);
            World.ChangeAreaFlag(area, AAF_WATER, true);
            World.ChangeAreaWaterHeight(area, self.Origin().z);
        }
    }
    
    /*
    ==============================================================
    OnRestore
    ==============================================================
    */
    
    void OnRestore(void)
    {
        if(self.Type() == AT_DYNAMIC_WATER2)
        {
            int area;
            
            self.Origin().z = self.StepHeight();
            bActivated = true;
            
            area = self.AreaID();
            
            if(area <= -1)
            {
                return;
            }
            
            World.ChangeAreaFlag(area, AAF_DAMAGE, false);
            World.ChangeAreaFlag(area, AAF_WATER, true);
            World.ChangeAreaWaterHeight(area, self.Origin().z);
        }
        else
        {
            self.Origin().z = self.StepHeight();
            World.ChangeAreaWaterHeight(self.AreaID(), self.Origin().z);
            
            bDrained = true;
            World.FloodFillAreaFlags(self.SectorIndex(), AAF_WATER, false);
        }
    }
};
